Escape From Echo Base — 4 of 54

Section 2 - Breaking and Fixing

A thing is either broken or unbroken. A thing is usually unbroken.

A thing can be fixable or unfixable. A thing is usually fixable.

To fix is a verb.

To try is a verb.

Understand the command "fix" as something new.

Fixing is an action applying to one thing.

Understand "fix [something]" as fixing.

Understand "repair [something]" as fixing.

Understand "mend [something]" as fixing.

Check an actor fixing a thing (this is the fixing a thing with an implicit tool rule):

if a tool is carried by the actor:

let T be a random tool carried by the actor;

say "[The actor] [try] to fix [the noun] with [the T].";

try the actor fixing the noun with T;

otherwise if a tool is part of the actor:

let T be a random tool part of the actor;

try the actor fixing the noun with T;

otherwise:

say "[The actor] [can't fix] [the noun] without a tool.";

stop the action.

Understand "fix [something] with [something]" as fixing it with.

Understand "repair [something] with [something]" as fixing it with.

Understand "mend [something] with [something]" as fixing it with.

Fixing it with is an action applying to two things.

Check an actor fixing an unfixable thing with a thing (this is the can't fix unfixable things rule):

say "[The noun] [can't be] fixed!";

stop the action.

Check an actor fixing an unbroken thing with a thing (this is the can't fix unbroken things rule):

say "[The noun] [are] not broken!";

stop the action.

Check an actor fixing a thing with a broken tool (this is the can't fix with a broken tool rule):

say "[The second noun] [are] broken and can't be used to fix [the noun].";

stop the action.

Carry out an actor fixing a broken thing with an unbroken tool:

now the noun is unbroken;

continue the action.

Report an actor fixing a thing with a tool:

say "[The actor] [fix] [the noun] with [their] [second noun]."